محیط ویژوال بیسک

گام دوم ایجاد یک ماژول

شما باید دستورات تابع خود را در یک Module (ماژول) بنویسید ،  از منوی Insert گزینه Module را بزنید . و اگر به project explorer نگاه کنید متوجه خواهید شد که یک ماژول جدید ایجاد شده است.

گام سوم ایجاد یک تابع در ماژول

یک تابع در ویژوال بیسیک قواعد استانداردی دارد که شما باید از این قواعد اطاعت کنید .

اولین قانون آن این است که یک تابع با دستورات استانداردی شروع و به پایان می‌رسد.

قانون دوم این است که هر تابع یک نوع دارد و ورودیهای یک تابع در داخل پرانتز مشخص می‌شوند.

قانون سوم ، نوع داده ورودیها (و خود تابع) باید مشخص شود.

این دستورات عبارتند از :

Private Function Test(Num As Integer) as Double

End Function

نام تابع ما test است و عبارت داخل پرانتز می‌گوید که این تابع یک ورودی دارد که نام آن ورودی Num است و integer  بیانگر آن است که این ورودی عددی صحیح است . (-32,768  تا 32,767 )

خروجی تابع از نوع double است و البته گذاشتن آن در همه موارد الزامی نیست ، گرچه بهتر است که مشخص شود. (برای اطلاع بیشتر به کتابهای برنامه نویسی مراجعه کنید.)

عبارت Private Function نشانگر شروع تابع و End Function برای پایان تابع است.

گام چهارم – نوشتن تابع

فرض کنید می‌خواهیم تابعی بنویسیم که یک عدد را بگیرد و آنرا در 10 ضرب کند!

اول باید تصمیم بگیریم که اسم این تابع را چه بگذاریم ، در حقیقت این اسم همان کلمه‌ای است که در اکسل برای استفاده از این تابع استفاده خواهیم کرد.

خوب اسم آنرا Test می‌گذاریم و می‌دانیم که این تابع باید یک ورودی داشته باشد و خوب چون به تازگی با نوع عدد Integer  آشنا شدیم (عدد صحیح) نوع این ورودی را هم Integer می‌گذاریم.

باید نامی برای این ورودی در نظر بگیریم ، این نام نباید یک نام آشنا ! برای VB باشد و بهتر است نامی با مسما در نظر بگیریم ، اینجا اسم این ورودی را Num می‌گذاریم.

پس در ماژول خود خواهیم نوشت :

Private Function Test(Num As Integer)

    Test = Num * 10

End Function

مثال 1) تابع بدست آوردن شماره رنگ یک سلول و رنگ قلم آن سلول

می‌خواهیم تابعی بنویسیم که شماره رنگ یک سلول (fill color) یا شماره رنگ قلم (font color) را مشخص کنیم.

(می‌دانیم که در اکسل از 56 رنگ می‌توان استفاده کرد که هر رنگ یک کد دارد مثلا کد رنگ قرمز 3 و آبی 5 است.)

·          نام تابع : CellColor

·          ورودی : تابع دو ورودی دارد ، ورودی اول آدرس سلول است و ورودی دوم مشخص می‌کند که ما می‌خواهیم رنگ زمینه سلول را داشته باشیم یا رنگ قلم آنرا .
اگر ورودی دوم عبارت fill بود رنگ زمینه مد نظر است و اگر font بود رنگ قلم.

·          نام ورودی اول MyRange و از نوع Range  است

·          نام ورودی دوم Mode و از نوع String است

·          اگر ورودی دوم داده نشده بود و یا مقادیری غیر fill و font بود ، خروجی تابع یک خطا به شکل #Mistake  باشد .

برای نوشتن این تابع از دستور شرطی IF به صورت زیر استفاده می‌کنیم :

Public Function Colorindex(MyRange As Range, Mode As String)

    Application.Volatile True

    If Mode = "font" Then

     Colorindex = MyRange.Font.Colorindex

    ElseIf Mode = "fill" Then

     Colorindex = MyRange.Interior.Colorindex

    Else

     Colorindex = "#Mistake"

    End If

End Function

عبارت As Range بیان می‌کند که ورودی اول یک خانه است.

عبارت String As بیان می‌کند که ورودی دوم یک رشته (متن – غیر عدد) است .

حال خانه A1 را به رنگ زرد و متن آنرا قرمز می‌کنیم و تابع را روی آن آزمایش می‌کنیم.

فرمولهای بکار رفته در خانه B1 و B2 را به ترتیب در D1 و D2 مشاهده می‌کنید.

مثال 2) سلولهایی را که رنگ آنها . . . را با هم جمع بزنید.

بهتر است از مثال قبل یک استفاده کاربردی کنیم. مثلا در یک محدوده می‌خواهیم سلولهای قرمز رنگ را با هم جمع بزنیم. (این سلولها می‌توانند با Conditional Formationg قرمز شده باشند.)

Public Function SumByColor(InRange As Range, WhatColorIndex As Integer) As Double

     Application.Volatile True

For Each C In InRange.Cells

    If C.Interior.Colorindex = WhatColorIndex Then

        SumByColor = SumByColor + C.Value

    End If

Next C

End Function

·          نام تابع : SumByColor و نوع آن را Double در نظر گرفتیم.

·          ورودی‌ها: محدوده که نام آنرا InRange و شماره رنگ  که نام آنرا  WhatColorIndex گذاشتیم و از نوع عدد صحیح است.

·          عبارت For Each C InRange دارد می‌گوید که C یک سلول از سلولهای محدود InRange است .

مثال 4- تابعی ایجاد کنید که اختلاف بزرگترین و کوچکترین عدد یک محدوده را حساب کند.

البته اینکار با خود اکسل بسیار ساده است و کافی است که فرمول =max(   ) – Min(   )  را بکار ببریم ، اما هدف این مثال اینست که نشان دهد چطور می‌توان در محیط ویژوال بیسیک از توابع استاندارد اکسل استفاده کرد.

Public Function max_min(InRange As Range) As Double

    Application.Volatile True

MaxNum = Application.WorksheetFunction.Max(InRange)

MinNum = Application.WorksheetFunction.Min(InRange)

max_min = MaxNum - MinNum

End Function

همانطور که می‌بینید با دستور application.worksheetfunction.xxx  که به جای xxx نام تابع استاندارد اکسل را می‌نویسیم.

مثال 4- می‌خواهیم تابعی بنویسیم که بتواند مقدار هزار، میلیون و میلیارد را در یک عدد تشخیص دهد و سپس کلمه "تومان" یا "ریال" را هم  به آن عدد اضافه کند . در صورتی که عدد معتبر نبود پیغام خطای مناسبی را اعلام کند.

مثلا اگر عدد 15000  وارد شد بنویسید : 15 هزار ریال (یا 15 هزار تومان)

با این مثال قصد داریم ورودیهای Optional را مرور کنیم. مثلا اگر تابع Vlookup را در نظر بگیریم ، آخرین ورودی آن انتخابی (optional) است ، بدین معنی که اگر کاربر مقداری را وارد نکند به طور پیش فرض مقدار True را در نظر می‌گیرد و در ضمن اگر کاربر خواست می‌تواند ورودی را به تابع بدهد.

حالت ساده این کار در VB به این صورت است که می‌نویسیم :

Public Function Test(Num as Integer, optional Num as Integer = True)

تفسیر  کد بالا به این صورت است که تابعی داریم به نام Test با دو ورودی.

ورودی اول آن مقداری است به نام Num و از نوع عدد صحیح است .

ورودی دوم آن مقداری است اختیاری ، یعنی کاربر می‌تواند ورودی دوم را ندهد و با تعریف بالا مقدار پیش فرض آن True در نظر گرفته شده که اگر کاربر مقداری را صریحاً به تابع اعلام نکند ، آنوقت مقدار دوم True در نظر گرفته خواهد شد و کار تابع با این مقدار شروع می‌شود.

اگر ورودی دوم داده نشود یا 1 یا True اعلام شود ، کلمه ریال در نظر گرفته خواهد شد.

اگر ورودی دوم False یا 0  داده شود ، کلمه تومان در نظر گرفته خواهد شد.

حال به نوشتن تابع مذکور می‌پردازیم :

Public Function PersianCurrency(MyNumber As String, Optional Mode As Boolean = True)

    Application.Volatile True

If Val(MyNumber) >= 0 Then

    Temp$ = MyNumber

    Cur$ = ""

End If

If Val(MyNumber) >= 1000 Then

    Temp$ = Mid(Trim(MyNumber), 1, Len(MyNumber) - 3)

    Cur$ = "هزار"

End If

If Val(MyNumber) >= 1000000 Then

    Temp$ = Mid(Trim(MyNumber), 1, Len(MyNumber) - 6)

        Cur$ = "ميليون"

End If

If Val(MyNumber) >= 1000000000 Then

    Temp$ = Mid(Trim(MyNumber), 1, Len(MyNumber) - 9)

        Cur$ = "ميليارد"

End If

If Mode = True Then C$ = "ريال" Else C$ = "تومان"

PersianCurrency = Temp$ & Cur$ & " " & C$

If Val(MyNumber) = 0 Then

    PersianCurrency = "مقدار يافت نشد"

End If

End Function

تست و خروجی این تابع را در مثال زیر مشاهد می‌کنید .

تذکر : مقدار True همان 1 است و مقدار False همان 0 است . (یعنی از هر کدام از این مقادیر می‌توان استفاده کرد.)

 این تابع جنبه تمرینی دارد و همه مقادیر اعداد را پوشش نمیدهد ،  فقط ارقامی که با صفر همراه هستند را می شناسد.